Function: cape--dict-list

cape--dict-list is a natively compiled function defined in cape.el.

Signature

(cape--dict-list INPUT)

Documentation

Return all words from cape-dict-file matching INPUT.

Source Code

;; Defined in /nix/store/nxaggkd0bn9kr2xfg9hyw77q51q20r8y-emacs-packages-deps/share/emacs/site-lisp/elpa/cape-20260927.2347/cape.el
(defun cape--dict-list (input)
  "Return all words from `cape-dict-file' matching INPUT."
  (let* ((inhibit-message t)
         (message-log-max nil)
         (default-directory
          (if (and (not (file-remote-p default-directory))
                   (file-directory-p default-directory))
              default-directory
            user-emacs-directory))
         (files (mapcar #'expand-file-name
                        (ensure-list
                         (if (functionp cape-dict-file)
                             (funcall cape-dict-file)
                           cape-dict-file))))
         (words
          (apply #'process-lines-ignore-status
                 "grep"
                 (concat "-Fh"
                         (and (cape--case-fold-p cape-dict-case-fold) "i")
                         (and cape-dict-limit (format "m%d" cape-dict-limit)))
                 input files)))
    (cons
     (apply-partially
      (if (and cape-dict-limit (length= words cape-dict-limit))
          #'equal #'string-search)
      input)
     (cape--case-replace-list cape-dict-case-replace input words))))