Function: claude-code-ide-rename-session

claude-code-ide-rename-session is an interactive and natively compiled function defined in claude-code-ide.el.

Signature

(claude-code-ide-rename-session)

Documentation

Rename a Claude Code instance of the current project.

The name shows up in the buffer name, session lists and prompts. Empty input converts the instance to the lowest free auto number.

Key Bindings

This command is not in any keymaps.

Source Code

;; Defined in /nix/store/yjvbhwl7p6zrbw9xlnni7y4hra8sa3pl-emacs-packages-deps/share/emacs/site-lisp/claude-code-ide.el
;;;###autoload
(defun claude-code-ide-rename-session ()
  "Rename a Claude Code instance of the current project.
The name shows up in the buffer name, session lists and prompts.
Empty input converts the instance to the lowest free auto number."
  (interactive)
  (let ((session (claude-code-ide--resolve-session 'prompt "Rename Claude instance: ")))
    (unless session
      (user-error "No Claude Code session for this project"))
    (let* ((project-dir (claude-code-ide-mcp-session-project-dir session))
           (old-name (claude-code-ide--session-display-name session))
           (new-name (claude-code-ide--read-instance-name
                      project-dir
                      (format "Rename %s to (empty for auto number): " old-name)
                      session)))
      (setf (claude-code-ide-mcp-session-instance-name session) new-name)
      (when-let* ((buffer (claude-code-ide-mcp-session-buffer session)))
        (when (buffer-live-p buffer)
          (with-current-buffer buffer
            (rename-buffer (claude-code-ide--instance-buffer-name project-dir new-name) t))))
      (claude-code-ide-log "Renamed Claude session %s to %s"
                           old-name
                           (claude-code-ide--session-display-name session)))))