Function: claude-code-ide-show-all

claude-code-ide-show-all is an interactive and natively compiled function defined in claude-code-ide.el.

Signature

(claude-code-ide-show-all &optional ALL-PROJECTS)

Documentation

Show every Claude Code instance of the current project.

Each hidden instance's window opens in its own side-window slot; already visible ones are left in place. Unlike claude-code-ide-toggle, this ignores the remembered panel set, so it also recovers instances whose windows were deleted manually. With prefix argument ALL-PROJECTS, show the instances of all projects.

Key Bindings

This command is not in any keymaps.

Source Code

;; Defined in /nix/store/yjvbhwl7p6zrbw9xlnni7y4hra8sa3pl-emacs-packages-deps/share/emacs/site-lisp/claude-code-ide.el
;;;###autoload
(defun claude-code-ide-show-all (&optional all-projects)
  "Show every Claude Code instance of the current project.
Each hidden instance's window opens in its own side-window slot;
already visible ones are left in place.  Unlike `claude-code-ide-toggle',
this ignores the remembered panel set, so it also recovers instances
whose windows were deleted manually.  With prefix argument
ALL-PROJECTS, show the instances of all projects."
  (interactive "P")
  (let ((sessions (if all-projects
                      (claude-code-ide-mcp--active-sessions)
                    (claude-code-ide-mcp--sessions-for-project
                     (claude-code-ide--get-working-directory))))
        (shown 0))
    (unless sessions
      (user-error "No Claude Code session%s"
                  (if all-projects "s" " for this project")))
    (dolist (session sessions)
      (let ((buffer (claude-code-ide-mcp-session-buffer session)))
        (when (and buffer
                   (buffer-live-p buffer)
                   (not (claude-code-ide--session-visible-p session)))
          (claude-code-ide--display-buffer-in-side-window buffer)
          (cl-incf shown))))
    (message (if (zerop shown)
                 "All Claude Code instances already visible"
               (format "Showing %d Claude Code instance%s"
                       shown (if (> shown 1) "s" ""))))))