Function: consult-eglot-symbols

consult-eglot-symbols is an interactive and natively compiled function defined in consult-eglot.el.

Signature

(consult-eglot-symbols)

Documentation

Interactively select a symbol from the current workspace.

Key Bindings

This command is not in any keymaps.

Source Code

;; Defined in /nix/store/3v6wy8b5xagm658m9sa8vhwzkykl5mv6-emacs-packages-deps/share/emacs/site-lisp/elpa/consult-eglot-20260613.1443/consult-eglot.el
;;;###autoload
(defun consult-eglot-symbols ()
  "Interactively select a symbol from the current workspace."
  (interactive)
  ;; Set `default-directory' here so we can show file names
  ;; relative to the project root.
  (if-let* ((servers (consult-eglot--servers))
            (default-directory
             (or (project-root (eglot--project (car servers)))
                 default-directory)))
      (progn
        (consult--read
         (consult--async-pipeline
          (consult--async-min-input)
          (consult--async-throttle)
          (consult-eglot--make-async-source servers)
          (consult--async-map #'consult-eglot--transformer)
          (consult--async-highlight))
         :require-match t
         :prompt "LSP Symbols: "
         :sort (not consult-eglot-sort-results)
         :initial nil
         :history '(:input consult-eglot--history)
         :category 'consult-eglot-symbols
         :lookup #'consult--lookup-candidate
         :group (consult--type-group consult-eglot-narrow)
         :narrow (consult--type-narrow consult-eglot-narrow)
         :state (consult-eglot--state))
        (run-hooks 'consult-after-jump-hook))
    (user-error "No server supporting symbol search")))