Function: eca-process--server-version

eca-process--server-version is a natively compiled function defined in eca-process.el.

Signature

(eca-process--server-version)

Documentation

Return the server version by running the eca binary with --version.

Anchors at the session's first workspace folder when a session exists, so remote (TRAMP) sessions report the remote binary version regardless of the buffer this is called from.

Source Code

;; Defined in /nix/store/jklqzw6pzz6j4jrbv8wy0iwgi7jlrbld-emacs-packages-deps/share/emacs/site-lisp/elpa/eca-20260928.1827/eca-process.el
(defun eca-process--server-version ()
  "Return the server version by running the eca binary with --version.
Anchors at the session's first workspace folder when a session
exists, so remote (TRAMP) sessions report the remote binary
version regardless of the buffer this is called from."
  (when-let* ((default-directory (or (-some-> (eca-session)
                                       (eca--session-workspace-folders)
                                       (car))
                                     default-directory))
              (binary (or (car eca-custom-command)
                          (executable-find "eca" (file-remote-p default-directory))
                          (and (f-exists? eca-server-install-path)
                               eca-server-install-path)))
              (output (ignore-errors
                        (string-trim
                         (if (file-remote-p binary)
                             (let ((default-directory (file-name-directory binary)))
                               (shell-command-to-string
                                (format "%s --version 2>/dev/null"
                                        (shell-quote-argument
                                         (file-local-name binary)))))
                           (shell-command-to-string
                            (format "%s --version 2>/dev/null"
                                    (shell-quote-argument
                                     (expand-file-name binary)))))))))
    (unless (string-empty-p output)
      output)))