Function: jinx--correct-suggestions

jinx--correct-suggestions is a natively compiled function defined in jinx.el.

Signature

(jinx--correct-suggestions WORD)

Documentation

Retrieve suggestions for WORD from all dictionaries.

Source Code

;; Defined in /nix/store/b5jnxgwmlp7hh60wfrx7amhrmrpfcqqi-emacs-packages-deps/share/emacs/site-lisp/elpa/jinx-20260926.912/jinx.el
(defun jinx--correct-suggestions (word)
  "Retrieve suggestions for WORD from all dictionaries."
  (let ((ht (make-hash-table :test #'equal))
        (list (cons nil nil)))
    (dolist (dict jinx--dicts)
      (let* ((desc (jinx--mod-describe dict))
             (group (format "Suggestions from dictionary ‘%s’ - %s"
                            (car desc) (cdr desc))))
        (dolist (w (jinx--mod-suggest dict word))
          (jinx--add-suggestion list ht w group))))
    (dolist (w (jinx--session-suggestions word))
      (jinx--add-suggestion list ht w "Suggestions from session"))
    (cl-loop
     for (key . fun) in jinx--save-keys do
     (cl-loop
      for (k w a) in (funcall fun 'format key word)
      for k2 = (propertize k 'face 'jinx-save 'rear-nonsticky t)
      for a2 = (format #(" [%s]" 0 5 (face jinx-annotation)) a)
      do (cl-loop
          for w2 in (list w (downcase w)) do
          (jinx--add-suggestion list ht (concat k2 w2) "Accept and save" a2))))
    (nreverse (car list))))