Function: jinx-remove-word

jinx-remove-word is an interactive and natively compiled function defined in jinx.el.

Signature

(jinx-remove-word)

Documentation

Remove word from personal dictionary, session, etc.

The word and dictionary are read via the minibuffer. The word defaults to the word at point.

Key Bindings

This command is not in any keymaps.

Source Code

;; Defined in /nix/store/b5jnxgwmlp7hh60wfrx7amhrmrpfcqqi-emacs-packages-deps/share/emacs/site-lisp/elpa/jinx-20260926.912/jinx.el
(defun jinx-remove-word ()
  "Remove word from personal dictionary, session, etc.
The word and dictionary are read via the minibuffer.  The word defaults
to the word at point."
  (interactive nil jinx-mode)
  (let* ((word (read-string
                "Remove word: "
                (pcase (jinx--bounds-of-word)
                  (`(,start . ,end)
                   (buffer-substring-no-properties start end)))))
         (_ (when (equal word "") (user-error "No input")))
         (actions
          (cl-loop for (key . fun) in jinx--save-keys nconc
                   (cl-loop for (k w a) in (funcall fun 'format key word)
                            for kw = (concat (substring k 1) w)
                            if (funcall fun 'has key kw)
                            collect (list a fun 'remove key kw))))
         (choice
          (or (assoc
               (completing-read
                (format "Remove ‘%s’ from: " word)
                (completion-table-with-metadata
                 (or actions
                     (user-error "Word ‘%s’ is not saved anywhere" word))
                 `((eager-display . t)
                   (display-sort-function . ,#'identity)
                   (cycle-sort-function . ,#'identity)))
                nil nil nil t)
               actions)
              (user-error "No selection"))))
    (apply (cdr choice))
    (jinx--cleanup)))