Function: logview--do-next-timestamp-gap

logview--do-next-timestamp-gap is a natively compiled function defined in logview.el.

Signature

(logview--do-next-timestamp-gap N SAME-THREAD-ONLY)

Source Code

;; Defined in /nix/store/3zkn9hgpv447zb8nrg55d9x2ynmmrk40-emacs-packages-deps/share/emacs/site-lisp/elpa/logview-20260218.2013/logview.el
(defun logview--do-next-timestamp-gap (n same-thread-only)
  (logview--assert 'timestamp)
  (when same-thread-only
    (logview--assert 'thread))
  (unless n
    (setq n 1))
  (logview--std-temporarily-widening
    (logview--locate-current-entry started-at-entry started-at
      (let ((thread (when same-thread-only
                      (logview--entry-group started-at-entry started-at logview--thread-group))))
        (when (< n 0)
          (logview--forward-entry -1 (when thread
                                       (lambda (entry start)
                                         (string-equal (logview--entry-group entry start logview--thread-group) thread)))))
        (logview--locate-current-entry entry start
          (let ((remaining (logview--forward-entry n (logview--entry-timestamp-gap-validator entry start thread)))
                (success   (when logview--last-found-large-gap
                             (format "Gap to the previous entry%s is %s s"
                                     (if same-thread-only " of this thread" "")
                                     (format logview--timestamp-gap-format-string logview--last-found-large-gap))))
                (failure   (format "No more large enough (%s s or more) gaps in timestamps%s"
                                   (logview--target-gap-length) (if same-thread-only " in this thread" ""))))
            (when (< n 0)
              (if (= remaining n)
                  (goto-char (logview--entry-message-start started-at-entry started-at))
                (logview--forward-entry 1)))
            (logview--maybe-pulse-current-entry 'timestamp-gap)
            (cond ((= n 0))
                  ((= remaining n)
                   (user-error "%s" failure))
                  ((= remaining 0)
                   (message "%s" success))
                  (t
                   (user-error "%s; %s" success (downcase failure))))))))))