Function: logview--iterate-entries-backward

logview--iterate-entries-backward is a natively compiled function defined in logview.el.

Signature

(logview--iterate-entries-backward POSITION CALLBACK &optional ONLY-VISIBLE VALIDATOR SKIP-CURRENT)

Documentation

Invoke CALLBACK for successive valid log entries backward.

See logview--iterate-entries-forward for details.

Source Code

;; Defined in /nix/store/3zkn9hgpv447zb8nrg55d9x2ynmmrk40-emacs-packages-deps/share/emacs/site-lisp/elpa/logview-20260218.2013/logview.el
(defun logview--iterate-entries-backward (position callback &optional only-visible validator skip-current)
  "Invoke CALLBACK for successive valid log entries backward.
See `logview--iterate-entries-forward' for details."
  (let ((entry+start (logview--do-locate-current-entry position)))
    (when entry+start
      (let ((entry    (car entry+start))
            (entry-at (cdr entry+start))
            (limit    (if only-visible (logview--point-min) (point-min))))
        (unless (and skip-current (< (setq entry-at (1- entry-at)) limit))
          (while (and (setq entry (or (get-text-property entry-at 'logview-entry)
                                      (progn (logview--find-region-entries (max (point-min) (- entry-at logview--lazy-region-size)) (1+ entry-at) t)
                                             (get-text-property entry-at 'logview-entry))))
                      (progn (unless (or (= entry-at (point-min))
                                         (not (eq (get-text-property (1- entry-at) 'logview-entry) entry)))
                               (setq entry-at (or (previous-single-property-change entry-at 'logview-entry)
                                                  (point-min))))
                             (when (or (and only-visible (invisible-p entry-at))
                                       (and validator (not (funcall validator entry entry-at)))
                                       (funcall callback entry entry-at))
                               (>= (setq entry-at (1- entry-at)) limit))))))))))