Function: logview-show-entries

logview-show-entries is an interactive and natively compiled function defined in logview.el.

Signature

(logview-show-entries &optional N INTERACTIVE)

Documentation

Show explicitly hidden entries.

By default, explicitly hidden entries between the current and the next visible are shown. If invoked with prefix argument, entries between the current entry and N'th after it (or before it if N is negative) are shown.

In Transient Mark mode, if the region is active and this command is invoked without prefix argument, show explicitly hidden entries in the region instead (i.e. work just like logview-show-region-entries).

Key Bindings

logview-mode-map s

Source Code

;; Defined in /nix/store/3zkn9hgpv447zb8nrg55d9x2ynmmrk40-emacs-packages-deps/share/emacs/site-lisp/elpa/logview-20260218.2013/logview.el
(defun logview-show-entries (&optional n interactive)
  "Show explicitly hidden entries.
By default, explicitly hidden entries between the current and the
next visible are shown.  If invoked with prefix argument, entries
between the current entry and N'th after it (or before it if N is
negative) are shown.

In Transient Mark mode, if the region is active and this command
is invoked without prefix argument, show explicitly hidden
entries in the region instead (i.e. work just like
`logview-show-region-entries')."
  (interactive (list (if (or current-prefix-arg (not (use-region-p)))
                         (prefix-numeric-value current-prefix-arg)
                       'use-region)))
  (if (eq n 'use-region)
      (logview-show-region-entries (point) (mark) interactive)
    (logview--assert)
    (unless n
      (setq n 1))
    (logview--std-temporarily-widening
      (logview--std-altering
        ;; Much like 'logview--iterate-successive-entries', but because of
        ;; peculiar semantics, not broken out into its own function.
        (when (/= n 0)
          (let ((direction (cl-signum n)))
            (funcall (if (> n 0) #'logview--iterate-entries-forward #'logview--iterate-entries-backward)
                     (point)
                     (lambda (entry entry-at)
                       (if (invisible-p entry-at)
                           (progn (logview--show-entry-callback entry entry-at)
                                  t)
                         (/= (setq n (- n direction)) 0)))
                     nil nil t))
          (logview--maybe-complain-about-movement n n))))))