Function: logview-toggle-region-entry-details

logview-toggle-region-entry-details is an interactive and natively compiled function defined in logview.el.

Signature

(logview-toggle-region-entry-details BEGIN END &optional ARG INTERACTIVE)

Documentation

Toggle whether details in the region are shown.

Toggling works like this: if at least one entry in the region has visible details, all are hidden. Otherwise, if all are already hidden, they are shown. If invoked with prefix argument, show details if the argument is positive, hide otherwise.

Entries that are in the region only partially are operated on as well.

Key Bindings

logview-mode-map D

Source Code

;; Defined in /nix/store/3zkn9hgpv447zb8nrg55d9x2ynmmrk40-emacs-packages-deps/share/emacs/site-lisp/elpa/logview-20260218.2013/logview.el
(defun logview-toggle-region-entry-details (begin end &optional arg interactive)
  "Toggle whether details in the region are shown.
Toggling works like this: if at least one entry in the region has
visible details, all are hidden.  Otherwise, if all are already
hidden, they are shown.  If invoked with prefix argument, show
details if the argument is positive, hide otherwise.

Entries that are in the region only partially are operated on as
well."
  (interactive (list (point) (mark) (or current-prefix-arg 'toggle) t))
  (logview--std-temporarily-widening
    (logview--std-altering
      (when (eq arg 'toggle)
        (setq arg 1)
        (logview--iterate-entries-in-region begin end (lambda (entry start)
                                                        (let ((details-start (logview--entry-details-start entry start)))
                                                          (if (or (null details-start)
                                                                  (memq logview--hidden-details-symbol (get-text-property details-start 'invisible)))
                                                              t
                                                            (setq arg 0)
                                                            nil)))))
      (let ((hide (<= (prefix-numeric-value arg) 0)))
        (logview--iterate-entries-in-region begin end (lambda (entry start)
                                                        (logview--update-entry-invisibility start (logview--entry-details-start entry start) (logview--entry-end entry start)
                                                                                            'propagate 'propagate hide))))
      (when interactive
        (setq deactivate-mark t)))))