Function: magit-diff-wash-signature

magit-diff-wash-signature is a natively compiled function defined in magit-diff.el.

Signature

(magit-diff-wash-signature OBJECT)

Source Code

;; Defined in /nix/store/irvbdy0zra0dn8fpd008f32x5ix6qm5v-emacs-packages-deps/share/emacs/site-lisp/elpa/magit-20261005.508/magit-diff.el
(defun magit-diff-wash-signature (object)
  (cond
    ((looking-at "^No signature")
     (delete-line))
    ((looking-at "^gpg: ")
     (let (title end)
       (save-excursion
         (while (looking-at "^\\(gpg: \\|\
Primary key fingerprint: \\|\
     Subkey fingerprint: \\)")
           (cond
             ((looking-at "^gpg: Good signature from")
              (setq title (magit--propertize-face
                           (buffer-substring (point) (line-end-position))
                           'magit-signature-good)))
             ((looking-at "^gpg: Can't check signature")
              (setq title (magit--propertize-face
                           (buffer-substring (point) (line-end-position))
                           '(italic bold)))))
           (forward-line))
         (setq end (point-marker)))
       (magit-insert-section (signature object title)
         (when title
           (magit-insert-heading title))
         (goto-char end)
         (set-marker end nil)
         (insert "\n"))))))