Function: majutsu-gerrit--account-request

majutsu-gerrit--account-request is a natively compiled function defined in majutsu-gerrit.el.

Signature

(majutsu-gerrit--account-request INPUT REMOTE)

Documentation

Return (URL . HEADERS) for an account suggestion request, or nil.

HEADERS includes auth-source Basic credentials when available.

Source Code

;; Defined in /nix/store/jagqw3nms546pad0gxi5f3wsckk6pji7-emacs-packages-deps/share/emacs/site-lisp/majutsu-gerrit.el
(defun majutsu-gerrit--account-request (input remote)
  "Return (URL . HEADERS) for an account suggestion request, or nil.
HEADERS includes auth-source Basic credentials when available."
  (when-let* ((input (string-trim input))
              ((not (string-empty-p input)))
              (spec (condition-case nil
                        (majutsu-gerrit-rest-current-spec remote)
                      (error nil))))
    (let* ((params (pcase majutsu-gerrit-account-completion-strategy
                     ('query
                      `(("q" . ,input)
                        ("n" . ,majutsu-gerrit-account-suggestion-limit)
                        ("o" . "DETAILS")
                        ("pp" . "0")))
                     (_
                      `(("suggest" . t)
                        ("q" . ,input)
                        ("n" . ,majutsu-gerrit-account-suggestion-limit)
                        ("pp" . "0")))))
           (url (majutsu-gerrit-rest--build-url spec "/accounts/" params))
           (headers (majutsu-gerrit-rest--headers spec nil
                                                  '(("Accept" . "application/json")))))
      (cons url headers))))