Function: majutsu-interactive--render-overlays

majutsu-interactive--render-overlays is a natively compiled function defined in majutsu-interactive.el.

Signature

(majutsu-interactive--render-overlays)

Documentation

Render overlays for current selections.

Source Code

;; Defined in /nix/store/jagqw3nms546pad0gxi5f3wsckk6pji7-emacs-packages-deps/share/emacs/site-lisp/majutsu-interactive.el
(defun majutsu-interactive--render-overlays ()
  "Render overlays for current selections."
  (majutsu-interactive--clear-overlays)
  (let ((selections majutsu-interactive--selections))
    (when selections
      (maphash
       (lambda (id spec)
         (if (majutsu-interactive--file-id-p id)
             (when-let* ((section (majutsu-interactive--find-file-section id)))
               (let ((ov (make-overlay (oref section start) (oref section end))))
                 (overlay-put ov 'face 'majutsu-interactive-selected-file)
                 (overlay-put ov 'evaporate t)
                 (push ov majutsu-interactive--overlays)))
           (when-let* ((section (majutsu-interactive--find-hunk-section id)))
             (cond
              ((eq spec :all)
               (let ((ov (make-overlay (oref section start) (oref section end))))
                 (overlay-put ov 'face 'majutsu-interactive-selected-hunk)
                 (overlay-put ov 'evaporate t)
                 (push ov majutsu-interactive--overlays)))
              ((consp spec)
               (let ((ranges (if (and spec (consp (car spec))) spec (list spec))))
                 (dolist (range ranges)
                   (let ((ov (make-overlay (car range) (cdr range))))
                     (overlay-put ov 'face 'majutsu-interactive-selected-region)
                     (overlay-put ov 'evaporate t)
                     (push ov majutsu-interactive--overlays)))))))))
       selections))))