Function: majutsu-jjdescription--build-font-lock-keywords

majutsu-jjdescription--build-font-lock-keywords is a natively compiled function defined in majutsu-jjdescription.el.

Signature

(majutsu-jjdescription--build-font-lock-keywords)

Documentation

Return font-lock rules for JJ description buffers.

Source Code

;; Defined in /nix/store/jagqw3nms546pad0gxi5f3wsckk6pji7-emacs-packages-deps/share/emacs/site-lisp/majutsu-jjdescription.el
(defun majutsu-jjdescription--build-font-lock-keywords ()
  "Return font-lock rules for JJ description buffers."
  (let ((comment-line-re (majutsu-jjdescription--comment-line-re))
        (change-id-re (majutsu-jjdescription--change-id-line-re))
        (describe-re (majutsu-jjdescription--describe-line-re))
        (heading-re (majutsu-jjdescription--heading-line-re))
        (file-re (majutsu-jjdescription--file-line-re))
        (stat-re (majutsu-jjdescription--stat-line-re))
        (summary-re (majutsu-jjdescription--summary-count-line-re))
        (ignore-rest-re (majutsu-jjdescription--ignore-rest-line-re)))
    `((majutsu-jjdescription--summary-matcher
       (0 '(face git-commit-summary font-lock-face git-commit-summary) t))
      ,@(when (and (integerp majutsu-jjdescription-summary-max-length)
                   (>= majutsu-jjdescription-summary-max-length 0))
          `((majutsu-jjdescription--overlong-summary-matcher
             (0 '(face git-commit-overlong-summary
                  font-lock-face git-commit-overlong-summary) t))))
      (,comment-line-re
       (0 '(face font-lock-comment-face font-lock-face font-lock-comment-face) append))
      (,ignore-rest-re
       (1 '(face git-commit-keyword font-lock-face git-commit-keyword) t))
      (,change-id-re
       (1 '(face git-commit-comment-heading font-lock-face git-commit-comment-heading) t)
       (2 (majutsu-jjdescription--change-id-face-spec) t))
      (,describe-re
       (1 '(face git-commit-comment-heading font-lock-face git-commit-comment-heading) t))
      (,heading-re
       (1 '(face git-commit-comment-heading font-lock-face git-commit-comment-heading) t))
      (,file-re
       (1 '(face git-commit-comment-action font-lock-face git-commit-comment-action) t)
       (2 '(face git-commit-comment-file font-lock-face git-commit-comment-file) t))
      (,stat-re
       (1 '(face git-commit-comment-file font-lock-face git-commit-comment-file) t)
       (2 '(face git-commit-comment-action font-lock-face git-commit-comment-action) t))
      (,summary-re
       (1 '(face git-commit-comment-file font-lock-face git-commit-comment-file) t))
      (majutsu-jjdescription--ignore-rest-comment-matcher
       (0 '(face font-lock-comment-face font-lock-face font-lock-comment-face) prepend)))))