Function: majutsu-log--get-value

majutsu-log--get-value is a natively compiled function defined in majutsu-log.el.

Signature

(majutsu-log--get-value MODE &optional USE-BUFFER-ARGS)

Documentation

Get log arguments for MODE.

Returns an (ARGS FILESETS) pair. USE-BUFFER-ARGS follows majutsu-prefix-use-buffer-arguments or majutsu-direct-use-buffer-arguments.

Source Code

;; Defined in /nix/store/jagqw3nms546pad0gxi5f3wsckk6pji7-emacs-packages-deps/share/emacs/site-lisp/majutsu-log.el
;;; Log State

(defun majutsu-log--get-value (mode &optional use-buffer-args)
  "Get log arguments for MODE.

Returns an (ARGS FILESETS) pair.  USE-BUFFER-ARGS follows
`majutsu-prefix-use-buffer-arguments' or
`majutsu-direct-use-buffer-arguments'."
  (setq use-buffer-args
        (pcase-exhaustive use-buffer-args
          ('prefix majutsu-prefix-use-buffer-arguments)
          ('direct majutsu-direct-use-buffer-arguments)
          ('nil majutsu-direct-use-buffer-arguments)
          ((or 'always 'selected 'current 'never)
           use-buffer-args)))
  (cond
   ((and (memq use-buffer-args '(always selected current))
         (eq major-mode mode))
    (list majutsu-buffer-log-args
          majutsu-buffer-log-filesets))
   ((and (memq use-buffer-args '(always selected))
         (when-let* ((buf (majutsu--get-mode-buffer mode (eq use-buffer-args 'selected))))
           (list (buffer-local-value 'majutsu-buffer-log-args buf)
                 (buffer-local-value 'majutsu-buffer-log-filesets buf)))))
   (t
    (list (majutsu-transient-default-value
           'majutsu-log mode
           'majutsu-log-current-arguments
           'majutsu-log-default-arguments)
          (or (get mode 'majutsu-log-current-filesets)
              (get mode 'majutsu-log-default-filesets))))))