Function: majutsu-process-buffer

majutsu-process-buffer is an interactive and natively compiled function defined in majutsu-process.el.

Signature

(majutsu-process-buffer &optional NODISPLAY)

Documentation

Display the current repository's process buffer.

If that buffer doesn't exist yet, then create it. Non-interactively return the buffer and unless optional NODISPLAY is non-nil also display it.

Key Bindings

majutsu-evolog-diff-mode-map $ majutsu-mode-map $

Source Code

;; Defined in /nix/store/jagqw3nms546pad0gxi5f3wsckk6pji7-emacs-packages-deps/share/emacs/site-lisp/majutsu-process.el
(defun majutsu-process-buffer (&optional nodisplay)
  "Display the current repository's process buffer.

If that buffer doesn't exist yet, then create it.  Non-interactively
return the buffer and unless optional NODISPLAY is non-nil also display
it."
  (interactive)
  (let* ((root (or (majutsu--buffer-root)
                   (majutsu-toplevel default-directory)
                   (majutsu--toplevel-safe default-directory)))
         (name (format "*majutsu-process: %s*"
                       (abbreviate-file-name (directory-file-name root))))
         (buffer (or (majutsu--find-mode-buffer 'majutsu-process-mode root)
                     (get-buffer-create name))))
    (with-current-buffer buffer
      (setq majutsu--default-directory root)
      (setq default-directory root)
      (if magit-root-section
          (when majutsu-process-log-max
            (majutsu--process-truncate-log))
        (majutsu-process-mode)
        (let ((inhibit-read-only t)
              (magit-insert-section--parent nil)
              (magit-insert-section--oldroot nil))
          (make-local-variable 'text-property-default-nonsticky)
          (magit-insert-section (processbuf)
            (insert "\n")))))
    (unless nodisplay
      (majutsu-display-buffer buffer))
    buffer))