Function: pdf-tools-install

pdf-tools-install is an interactive and natively compiled function defined in pdf-tools.el.

Signature

(pdf-tools-install &optional NO-QUERY-P SKIP-DEPENDENCIES-P NO-ERROR-P FORCE-DEPENDENCIES-P)

Documentation

Install PDF-Tools in all current and future PDF buffers.

If the pdf-info-epdfinfo-program is not running or does not appear to be working, attempt to rebuild it. If this build succeeded, continue with the activation of the package. Otherwise fail silently, i.e. no error is signaled.

Build the program (if necessary) without asking first, if NO-QUERY-P is non-nil.

Don't attempt to install system packages, if SKIP-DEPENDENCIES-P is non-nil.

Do not signal an error in case the build failed, if NO-ERROR-P is non-nil.

Attempt to install system packages (even if it is deemed unnecessary), if FORCE-DEPENDENCIES-P is non-nil.

Note that SKIP-DEPENDENCIES-P and FORCE-DEPENDENCIES-P are mutually exclusive.

Note further, that you can influence the installation directory by setting pdf-info-epdfinfo-program to an appropriate value (e.g. ~/bin/epdfinfo) before calling this function.

See pdf-view-mode and pdf-tools-enabled-modes.

Key Bindings

This command is not in any keymaps.

Source Code

;; Defined in /nix/store/63h5z2vmzn0mfavcxi2idi23g5xcgkbl-emacs-packages-deps/share/emacs/site-lisp/elpa/pdf-tools-20260102.1101/pdf-tools.el
;; * ================================================================== *
;; * Initialization
;; * ================================================================== *

;;;###autoload
(defun pdf-tools-install (&optional no-query-p skip-dependencies-p
                                    no-error-p force-dependencies-p)
  "Install PDF-Tools in all current and future PDF buffers.

If the `pdf-info-epdfinfo-program' is not running or does not
appear to be working, attempt to rebuild it.  If this build
succeeded, continue with the activation of the package.
Otherwise fail silently, i.e. no error is signaled.

Build the program (if necessary) without asking first, if
NO-QUERY-P is non-nil.

Don't attempt to install system packages, if SKIP-DEPENDENCIES-P
is non-nil.

Do not signal an error in case the build failed, if NO-ERROR-P is
non-nil.

Attempt to install system packages (even if it is deemed
unnecessary), if FORCE-DEPENDENCIES-P is non-nil.

Note that SKIP-DEPENDENCIES-P and FORCE-DEPENDENCIES-P are
mutually exclusive.

Note further, that you can influence the installation directory
by setting `pdf-info-epdfinfo-program' to an appropriate
value (e.g. ~/bin/epdfinfo) before calling this function.

See `pdf-view-mode' and `pdf-tools-enabled-modes'."
  (interactive)
  (if (or (pdf-info-running-p)
          (ignore-errors (pdf-info-check-epdfinfo) t))
      (pdf-tools-install-noverify)
    (let ((target-directory
           (or (and (stringp pdf-info-epdfinfo-program)
                    (file-name-directory
                     pdf-info-epdfinfo-program))
               pdf-tools-directory)))
      (if (or no-query-p
              (y-or-n-p "Need to (re)build the epdfinfo program, do it now ?"))
          (pdf-tools-build-server
           target-directory
           skip-dependencies-p
           force-dependencies-p
           (lambda (executable)
             (let ((msg (format
                         "Building the PDF Tools server %s"
                         (if executable "succeeded" "failed"))))
               (if (not executable)
                   (funcall (if no-error-p #'message #'error) "%s" msg)
                 (message "%s" msg)
                 (setq pdf-info-epdfinfo-program executable)
                 (let ((pdf-info-restart-process-p t))
                   (pdf-tools-install-noverify))))))
        (message "PDF Tools not activated")))))