Function: pdf-view-bookmark-make-record

pdf-view-bookmark-make-record is a natively compiled function defined in pdf-view.el.

Signature

(pdf-view-bookmark-make-record &optional NO-PAGE NO-SLICE NO-SIZE NO-ORIGIN)

Documentation

Create a bookmark PDF record.

The optional, boolean args exclude certain attributes.

Source Code

;; Defined in /nix/store/63h5z2vmzn0mfavcxi2idi23g5xcgkbl-emacs-packages-deps/share/emacs/site-lisp/elpa/pdf-tools-20260102.1101/pdf-view.el
(defun pdf-view-bookmark-make-record  (&optional no-page no-slice no-size no-origin)
  ;; TODO: add NO-PAGE, NO-SLICE, NO-SIZE, NO-ORIGIN to the docstring.
  "Create a bookmark PDF record.

The optional, boolean args exclude certain attributes."
  (or pdf-view--bookmark-to-restore
      (let ((win (car (cl-find-if #'window-live-p image-mode-winprops-alist
                                  :key #'car-safe))))
        (cons (buffer-name)
              (append (bookmark-make-record-default
                       nil t (if pdf-view-roll-minor-mode (point) 1))
                      `(,(unless no-page
                           (cons 'page (pdf-view-current-page win)))
                        ,(unless no-slice
                           (cons 'slice (and win (pdf-view-current-slice win))))
                        ,(unless no-size
                           (cons 'size pdf-view-display-size))
                        ,(unless no-origin
                           (cons 'origin
                                 (and win
                                      (let* ((edges (pdf-util-image-displayed-edges
                                                     win (eq (window-buffer win) (current-buffer)))))
                                        (pdf-util-scale-pixel-to-relative
                                         (cons (car edges) (cadr edges)) nil
                                         (eq (current-buffer) (window-buffer)) win)))))
                        (handler . pdf-view-bookmark-jump-handler)))))))