Function: tuareg-syntax-propertize

tuareg-syntax-propertize is a natively compiled function defined in tuareg.el.

Signature

(tuareg-syntax-propertize START END)

Source Code

;; Defined in /nix/store/6mbh851dhnag8f92qfrlh9ckldzwf6c6-emacs-packages-deps/share/emacs/site-lisp/elpa/tuareg-20260626.936/tuareg.el
(defun tuareg-syntax-propertize (start end)
  (goto-char start)
  (tuareg--syntax-quotation end)
  (funcall
   (syntax-propertize-rules
    ;; When we see a '"', knowing whether it's a literal char (as opposed to
    ;; the end of a string followed by the beginning of a literal char)
    ;; requires checking syntax-ppss as in:
    ;; ("\\_<\\('\"'\\)"
    ;;  (1 (unless (nth 3 (save-excursion (syntax-ppss (match-beginning 0))))
    ;;       (string-to-syntax "\""))))
    ;; Not sure if it's worth the trouble since adding a space between the
    ;; string and the literal char is easy enough and is the usual
    ;; style anyway.
    ;; For all other cases we don't need to check syntax-ppss because, if the
    ;; first quote is within a string (or comment), the whole match is within
    ;; the string (or comment), so the syntax-properties don't hurt.
    ;;
    ;; Note: we can't just use "\\<" here because syntax-propertize is also
    ;; used outside of font-lock.
    ("\\_<\\('\\)\\(?:[^'\\\n]\\|\\\\.[^\\'\n \")]*\\)\\('\\)"
     (1 "\"") (2 "\""))
    ("\\({\\)[[:lower:]_]*|"
     (1 (prog1 "|" (tuareg--syntax-quotation end))))
    )
   (point) end))