Function: verb-export-request-on-point

verb-export-request-on-point is an interactive and natively compiled function defined in verb.el.

Signature

(verb-export-request-on-point &optional NAME)

Documentation

Export the request specification on point.

Interactively, prompt the user for an export function, and call that function with the request specification object. See the verb-export-functions variable for more details. If called from Lisp, use the export function under NAME. If NAME is nil, prompt the user anyways.

No HTTP request is sent, unless the export function does this explicitly. Lisp code tags are evaluated when exporting.

Key Bindings

verb-command-map C-e

Source Code

;; Defined in /nix/store/8jnfn8w2mxcxbr2crbklcnija9m0zlkq-emacs-packages-deps/share/emacs/site-lisp/elpa/verb-20260818.1921/verb.el
;;;###autoload
(defun verb-export-request-on-point (&optional name)
  "Export the request specification on point.
Interactively, prompt the user for an export function, and call that
function with the request specification object.  See the
`verb-export-functions' variable for more details.  If called from
Lisp, use the export function under NAME.  If NAME is nil, prompt the
user anyways.

No HTTP request is sent, unless the export function does this
explicitly.  Lisp code tags are evaluated when exporting."
  (interactive)
  (verb--ensure-verb-mode)
  (let ((rs (verb--request-spec-from-hierarchy))
        (prompt (string-join
                 (append
                  (mapcar (lambda (x)
                            (format "[%c]: Export to %s" (nth 1 x) (nth 0 x)))
                          verb-export-functions)
                  '("Choice: "))
                 "\n"))
        (choice))
    (unless name
      (setq choice (read-char-choice prompt
                                     (mapcar (lambda (x)
                                               (nth 1 x))
                                             verb-export-functions))))
    (mapc (lambda (x)
            (when (or (string= name (nth 0 x))
                      (equal choice (nth 1 x)))
              (funcall (nth 2 x) rs)
              (verb-util--log nil 'I "Exported request to %s format"
                              (nth 0 x))))
          verb-export-functions)))