Function: verb-send-request-on-point

verb-send-request-on-point is an interactive and natively compiled function defined in verb.el.

Signature

(verb-send-request-on-point WHERE &optional ARG)

Documentation

Send the request specified by the selected heading's text contents.

After the request has been sent, return the response buffer (the buffer where the response will be loaded into).

Note that the contents of all parent headings are considered as well; see verb--request-spec-from-hierarchy to see how this is done.

The buffer containing the response is shown (or not shown) in different ways, depending on the value of WHERE:

- other-window: Show the response buffer on another window and
  select it.
- stay-window: Show the response buffer on another window, but
  keep the current one selected.
- this-window: Show the response buffer in the current window.
- minibuffer: Show the response status on the minibuffer, but don't
  show the response buffer anywhere.
- nil: Send the request but do not show the response buffer nor the
  response status anywhere.

The response buffer won't have any contents until the HTTP response has been received. For all valid values of WHERE except nil, the response status will be shown on the minibuffer when the response is received.

If prefix argument ARG is non-nil, allow the user to quickly edit the request before it is sent. The changes made will not affect the contents of the current buffer and will be discarded after the request is sent.

The verb-post-response-hook hook is called after a response has been received.

Key Bindings

verb-command-map C-f

Source Code

;; Defined in /nix/store/8jnfn8w2mxcxbr2crbklcnija9m0zlkq-emacs-packages-deps/share/emacs/site-lisp/elpa/verb-20260818.1921/verb.el
;;;###autoload
(defun verb-send-request-on-point (where &optional arg)
  "Send the request specified by the selected heading's text contents.
After the request has been sent, return the response buffer (the
buffer where the response will be loaded into).

Note that the contents of all parent headings are considered as well;
see `verb--request-spec-from-hierarchy' to see how this is done.

The buffer containing the response is shown (or not shown) in
different ways, depending on the value of WHERE:

- `other-window': Show the response buffer on another window and
  select it.
- `stay-window': Show the response buffer on another window, but
  keep the current one selected.
- `this-window': Show the response buffer in the current window.
- `minibuffer': Show the response status on the minibuffer, but don't
  show the response buffer anywhere.
- nil: Send the request but do not show the response buffer nor the
  response status anywhere.

The response buffer won't have any contents until the HTTP response
has been received.  For all valid values of WHERE except nil, the
response status will be shown on the minibuffer when the response is
received.

If prefix argument ARG is non-nil, allow the user to quickly edit the
request before it is sent.  The changes made will not affect the
contents of the current buffer and will be discarded after the request
is sent.

The `verb-post-response-hook' hook is called after a response has been
received."
  (interactive (list 'this-window current-prefix-arg))
  (verb--ensure-verb-mode)
  (when (and where
             (not (member where
                          '(other-window stay-window this-window minibuffer))))
    (user-error "Invalid value for WHERE: %s" where))
  (let* ((verb--inhibit-code-tags-evaluation arg)
         (rs (verb--request-spec-from-hierarchy)))
    (if arg
        ;; If ARG is non-nil, setup a buffer to edit the request.
        (verb--setup-temp-request-buffer rs
                                         (selected-window)
                                         verb--vars
                                         where)
      ;; If ARG is nil, just send the request.
      (verb--request-spec-send rs where))))