Variable: neocaml--compilation-error-regexp

neocaml--compilation-error-regexp is a variable defined in neocaml.el.

Value

"^\\(?:\\(?9:       \\)\\|[	 ]*\\)\\(?1:\\(?:File \\|\\(?:Called from\\|R\\(?:\\(?:aised\\(?: by primitive operation\\)?\\|e-raised\\) at\\)\\).* file \\)\\(?2:\"?\\)\\(?3:[^	\n \",<>]+\\)\\2\\(?: (inlined)\\)?, lines? \\(?4:[0-9]+\\)\\(?:-\\(?5:[0-9]+\\)\\)?\\(?:, characters? \\(?6:[0-9]+\\)\\(?:-\\(?7:[0-9]+\\)\\)?\\)?:?\\)\\(?:\n[	 ]*\\(?:\\(?:[0-9]+ | .*\\|\\^+\\)\n[	 ]*\\)*\\(?8:\\(?:Alert\\|Warning\\)[^\n:]*:\\)\\)?"

Documentation

Regexp matching OCaml compiler error, warning, and backtrace messages.

Source Code

;; Defined in /nix/store/ahssdx4rwzyxhyhavpn0bkznk13xrggi-emacs-packages-deps/share/emacs/site-lisp/elpa/neocaml-20260907.2015/neocaml.el
;;;; Compilation support

(defconst neocaml--compilation-error-regexp
  (eval-when-compile
    (rx bol
        ;; Leading whitespace: 7 spaces = ancillary location (info level),
        ;; any other whitespace = default severity (error/warning per group 8).
        (or (group-n 9 "       ")
            (* (in " \t")))
        (group-n 1
                 (or "File "
                     ;; Exception backtraces (OCaml >= 4.11 includes function names)
                     (seq (or "Raised at" "Re-raised at"
                              "Raised by primitive operation at"
                              "Called from")
                          (* nonl)
                          " file "))
                 (group-n 2 (? "\""))
                 (group-n 3 (+ (not (in "\t\n \",<>"))))
                 (backref 2)
                 (? " (inlined)")
                 ", line" (? "s") " "
                 (group-n 4 (+ (in "0-9")))
                 (? "-" (group-n 5 (+ (in "0-9"))))
                 (? ", character" (? "s") " "
                    (group-n 6 (+ (in "0-9")))
                    (? "-" (group-n 7 (+ (in "0-9")))))
                 (? ":"))
        ;; Skip source-code snippets and match Warning/Alert on next line
        (? "\n"
           (* (in "\t "))
           (* (or (seq (+ (in "0-9"))
                       " | "
                       (* nonl))
                  (+ "^"))
              "\n"
              (* (in "\t ")))
           (group-n 8 (or "Warning" "Alert")
                    (* (not (in ":\n")))
                    ":"))))
  "Regexp matching OCaml compiler error, warning, and backtrace messages.")