Variable: verb-mode

verb-mode is a buffer-local variable defined in verb.el.

Documentation

Non-nil if Verb mode is enabled.

Use the command verb-mode(var)/verb-mode(fun) to change this variable.

Key Bindings

This command is not in any keymaps.

Source Code

;; Defined in /nix/store/8jnfn8w2mxcxbr2crbklcnija9m0zlkq-emacs-packages-deps/share/emacs/site-lisp/elpa/verb-20260818.1921/verb.el
;;;###autoload
(define-minor-mode verb-mode
  "Minor mode for organizing and making HTTP requests from Emacs.
This mode acts as an extension to Org mode.  Make sure you enable it
on buffers using Org as their major mode.

See the documentation in URL `https://github.com/federicotdn/verb' for
more details on how to use it."
  :lighter " Verb"
  :group 'verb
  (if verb-mode
      ;; Enable verb-mode.
      (progn
        (verb--setup-font-lock-keywords)
        (when verb-enable-elisp-completion
          (add-hook 'completion-at-point-functions
                    #'verb-elisp-completion-at-point
                    nil 'local))
        (when verb-enable-ctrl-c-ctrl-c
          (add-hook 'org-ctrl-c-ctrl-c-final-hook
                    #'verb-ctrl-c-ctrl-c-context-behavior
                    nil 'local))
        (add-hook 'post-command-hook #'verb--var-preview nil t)
        (when (buffer-file-name)
          (verb-util--log nil 'I
                          "Verb mode enabled in buffer: %s"
                          (buffer-name))
          (verb-util--log nil 'I "Verb version: %s" verb-version)
          (verb-util--log nil 'I "Org version: %s, GNU Emacs version: %s"
                          (org-version)
                          emacs-version)))
    ;; Disable verb-mode.
    (verb--setup-font-lock-keywords t)
    (remove-hook 'completion-at-point-functions
                 #'verb-elisp-completion-at-point
                 'local)))